// Запись, четение и стирание ячеек в EEPROM 24C02, 256 x 8 (2K)
// 30.06.2017, Arduino IDE v1.8.3, ClassicCarsToday.ru
//---------------------------------------------------------------------------------------------------------
#include "at24c02.h"
//       _____
//  A0 -|  ^  |- VCC
//  A1 -|     |- WP(GND)
//  A2 -|     |- SCL
// GND -|_____|- SDA

at24c02 eeprom(0x50);                             // 0x50 = A0(GND), A1(GND), A2(GND)

char ch;
//---------------------------------------------------------------------------------------------------------
void setup() {
  Serial.begin(57600);

  eeprom.init();
  // Wire.setClock(400000L);                      // 100kHz / 400kHz
}
//---------------------------------------------------------------------------------------------------------
void loop() {
  Serial.println("EEPROM 24C02:");
  Serial.println("r - Read");
  Serial.println("b - Blank (write 0xFF)");
  Serial.println("x - Write random data");
  Serial.println();

  while (1) {
    if (Serial.available() > 0) {
      ch = Serial.read();

      if (ch == 'r')                              // read
        eeprom_read();

      if (ch == 'b') {                            // blank and read
        eeprom_blank();
        eeprom_read();
      }

      if (ch == 'x') {                            // write random data and read
        eeprom_write_random_data();
        eeprom_read();
      }
    }
  }
}
//---------------------------------------------------------------------------------------------------------
void eeprom_read() {
  Serial.print("         ");
  for (uint8_t i = 0; i < 16; i++) {
    Serial.print('0');
    Serial.print(i, HEX);
    Serial.print(' ');
  }
  Serial.println();

  for (uint8_t j = 0; j < 16; j++) {
    Serial.print("000000");
    Serial.print(j, HEX);
    Serial.print("0 ");
    for (uint8_t k = 0; k < 16; k++) {
      uint8_t read_byte = eeprom.read(j * 16 + k);
      if (read_byte < 16)
        Serial.print('0');
      Serial.print(read_byte, HEX);
      Serial.print(' ');
    }
    Serial.println();
  }
  Serial.println();
}
//---------------------------------------------------------------------------------------------------------
void eeprom_blank() {
  for (uint16_t i = 0; i < 256; i++)
    eeprom.write(i, 0xFF);
}
//---------------------------------------------------------------------------------------------------------
void eeprom_write_random_data() {
  for (uint16_t i = 0; i < 256; i++)
    // eeprom.write(i, random(0, 256));
    eeprom.update(i, random(0, 256));
}